【Excel VBA】PDFを開く方法5選！複数一括OPENも可！

VBAでPDFを開きたいときはないでしょうか。

けど、そんな中で悩むことは、

ですよね。

今回はそんなお悩みを解決する

についてまとめます！

VBAでPDFを開くするイメージ

VBAでPDFを開くイメージについて説明をします。

Excel側にPDF保存先パスを入力した一覧を作成します。

VBAを実行すると、ExcelリストにあるPDFファイルが開きます。

そんなPDFファイルを開く方法を5パターン紹介していきます。

それでは早速試してみましょう。

VBAでPDFを開く方法1：ハイパーリンクとして開く

VBAでPDFを開く方法1のハイパーリンクとして開く方法について説明をします。

PDF保存先リストを準備する

Excel側にPDF保存先パス一覧をA列に作成します。

このリストに沿って、Excelリスト分のPDFファイルが開く形となります。

VBAコード

サンプルのVBAコードは以下の通りです。

Sub PDFを開く_その1()

    Dim intEndrow As Integer
    Dim i As Integer
    
    'マクロ実装ブックの１シート目を対象にします。
    With ThisWorkbook.Worksheets(1)
    
        'PDF出力先リストの最終行を取得します。
        intEndrow = .Cells(Rows.Count, 1).End(xlUp).Row
        
        '２行目から最終行まで処理を繰り返します。
        For i = 2 To intEndrow

            'ハイパーリンクとしてPDFを開きます。
            ThisWorkbook.FollowHyperlink .Cells(i, 1).Value
 
        Next i
    
    End With

End Sub

VBAを設定する

マクロ実装ブックの１シート目を対象にします。シート名を指定したい場合はシート番号「1」をシート名に変更してください。

PDF出力先リストの最終行を取得します。Excelブック1シート目のA列を対象としていますので、変更する場合は列番号「1」を別の列番号に変更してください。

２行目から最終行まで処理を繰り返します。開始行が2行目でない場合は変更をしてください。

タカヒロ

設定内容はほかのパターンも同様ですので、2つめ以降の設定に関する説明は割愛します。

VBAの実装

VBAの実装方法については
VBAの実装手順
をご参照ください。

VBAを実行する

VBAを実行してみましょう。

PDFが開きましたね。

VBAの説明

VBAについて説明をします。

FollowHyperlinkメソッドを使い、PDFのパスをハイパーリンクとして開きます。

タカヒロ

ThisWorkbookはVBAを実行するブックを指します。

FollowHyperlinkメソッドの構文およびパラメータは以下の通りです。

パラメータ

参考：https://docs.microsoft.com/ja-jp/office/vba/api/access.application.followhyperlink

VBAでPDFを開く方法2：Excelのハイパーリンクを開く

VBAでPDFを開く方法2：Excelのハイパーリンクを開く方法について説明をします。

PDF保存先リストにハイパーリンクを付与する

Excel側に入力したPDF保存先パス一覧にハイパーリンクを付与していきます。

前回はテキストデータをハイパーリンクとして開きましたが、
今回はExcelのハイパーリンク情報をそのまま読み取ってPDFファイルを開いていきます。

VBAコード

サンプルのVBAコードは以下の通りです。

Sub PDFを開く_その2()

    Dim intEndrow As Integer
    Dim i As Integer
    
    'マクロ実装ブックの１シート目を対象にします。
    With ThisWorkbook.Worksheets(1)
    
        'PDF出力先リストの最終行を取得します。
        intEndrow = .Cells(Rows.Count, 1).End(xlUp).Row
        
        '２行目から最終行まで処理を繰り返します。
        For i = 2 To intEndrow

            'ハイパーリンクとしてPDFを開きます。
            .Cells(i, 1).Hyperlinks(1).Follow NewWindow:=True
 
        Next i
    
    End With

End Sub

VBAを実行する

VBAを実行してみましょう。

PDFが開きましたね。

VBAの説明

VBAについて説明をします。

Hyperlinksコレクション一つ目にあるハイパーリンクをHyperlink.Followメソッドを使い、PDFファイルを開きます。

FollowHyperlinkメソッドの構文およびパラメータは以下の通りです。

パラメータ

参考：https://docs.microsoft.com/ja-jp/office/vba/api/excel.hyperlink.follow

タカヒロ

ハイパーリンクに関する詳細や応用技については以下の記事に詳しく乗っています。
よろしければご参考ください。

VBAでPDFを開く方法3：WshShellオブジェクトのRunメソッドを使う

VBAでPDFを開く方法3：WshShellオブジェクトのRunメソッドでPDFを開く方法について説明をします。

Excel側のPDFパス一覧はテキストのみ、ハイパーリンク付きどちらでも問題ありません。

VBAコード

サンプルのVBAコードは以下の通りです。

Sub PDFを開く_その3()

    Dim intEndrow As Integer
    Dim i As Integer
    
    'マクロ実装ブックの１シート目を対象にします。
    With ThisWorkbook.Worksheets(1)
    
        'PDF出力先リストの最終行を取得します。
        intEndrow = .Cells(Rows.Count, 1).End(xlUp).Row
        
        '２行目から最終行まで処理を繰り返します。
        For i = 2 To intEndrow

            'WshShellオブジェクトのRunメソッドでPDFを開きます。高速です。
            CreateObject("WScript.Shell").Run .Cells(i, 1).Value
        Next i
    
    End With

End Sub

VBAを実行する

VBAを実行してみましょう。

PDFが開きましたね。

VBAの説明

VBAについて説明をします。

WshShellオブジェクトのRunメソッドでPDFファイルを開きます。方法1，2よりは高速です。

VBAでPDFを開く方法4：WshShellオブジェクトのExecメソッドでchrome.exeを使う

VBAでPDFを開く方法4：WshShellオブジェクトのExecメソッドでchrome.exeを使いPDFを開く方法について説明をします。

Excel側のPDFパス一覧はテキストのみ、ハイパーリンク付きどちらでも問題ありません。

VBAコード

サンプルのVBAコードは以下の通りです。

Sub PDFを開く_その4()

    Dim intEndrow As Integer
    Dim i As Integer
    
    'マクロ実装ブックの１シート目を対象にします。
    With ThisWorkbook.Worksheets(1)
    
        'PDF出力先リストの最終行を取得します。
        intEndrow = .Cells(Rows.Count, 1).End(xlUp).Row
        
        '２行目から最終行まで処理を繰り返します。
        For i = 2 To intEndrow

            'WshShellオブジェクトのExecメソッドでchrome.exeを使いPDFを開きます。高速です。
            CreateObject("WScript.Shell").Exec ("C:\Program Files\Google\Chrome\Application\chrome.exe" & " " & .Cells(i, 1).Value)
        Next i
    
    End With

End Sub

VBAを実行する

VBAを実行してみましょう。

PDFが開きましたね。

VBAの説明

VBAについて説明をします。

WshShellオブジェクトのExecメソッドでchrome.exeを使いPDFを開きます。方法1，2よりは高速です。

タカヒロ

Chromeの実行先パスはChromeアイコンを右クリックしてプロパティから参照してください。
なおChrome以外にAdobeAcrobatやEdgeなどの指定が可能です。

類似のコード

Sub PDFを開く_その4a()

    Dim intEndrow As Integer
    Dim i As Integer
    
    'マクロ実装ブックの１シート目を対象にします。
    With ThisWorkbook.Worksheets(1)
    
        'PDF出力先リストの最終行を取得します。
        intEndrow = .Cells(Rows.Count, 1).End(xlUp).Row
        
        '２行目から最終行まで処理を繰り返します。
        For i = 2 To intEndrow

            'Shellでchrome.exeを使いPDFを開きます。高速です。
            Shell "C:\Program Files\Google\Chrome\Application\chrome.exe" & " " & .Cells(i, 1).Value, vbNormalFocus
        Next i
    
    End With

End Sub

Shellでchrome.exeを使いPDFを開くこともできます。

VBAでPDFを開く方法5：Shell.ShellExecuteメソッドを使う

VBAでPDFを開く方法5：Shell.ShellExecuteメソッドでPDFを開く方法について説明をします。

Excel側のPDFパス一覧はテキストのみ、ハイパーリンク付きどちらでも問題ありません。

VBAコード

サンプルのVBAコードは以下の通りです。

Sub PDFを開く_その5()

    Dim intEndrow As Integer
    Dim i As Integer
    
    'マクロ実装ブックの１シート目を対象にします。
    With ThisWorkbook.Worksheets(1)
    
        'PDF出力先リストの最終行を取得します。
        intEndrow = .Cells(Rows.Count, 1).End(xlUp).Row
        
        '２行目から最終行まで処理を繰り返します。
        For i = 2 To intEndrow

            'Shell.ShellExecuteメソッドでPDFを開きます。高速です。
            CreateObject("Shell.Application").ShellExecute .Cells(i, 1).Value
        Next i
    
    End With

End Sub

VBAを実行する

VBAを実行してみましょう。

PDFが開きましたね。

VBAの説明

VBAについて説明をします。

Shell.ShellExecuteメソッドでPDFを開きます。方法1，2よりは高速です。

Shell.ShellExecuteメソッドの構文およびパラメータは以下の通りです。

パラメータ

参考：https://docs.microsoft.com/ja-jp/windows/win32/shell/shell-shellexecute

VBAの実装手順

実装手順は以下の通りです。

Excel側にVBAを実装していきます。

①Excelを新規に開き、「開発」タブをクリックし、「VisualBasic」をクリックします。
もしくはショートカットキー「Alt」＋「F11」でもOKです。

②標準モジュールを追加します。
左ペインのVBAProjectを右クリックし、「挿入」、「標準モジュール」を選択します。

③右ペインのウインドウに上記のVBAを入力します。

こちらで完了です。

VBAを実行する

では早速VBAの実行をしてみましょう。

①「開発」タブの「VBA」をクリックし実行したいマクロを選択し、「実行」をクリックします。

②処理がされたことが確認できれば完了です。

さいごに

いかがでしょうか。

今回は、

についてまとめました。

また、他にも便利な方法がありますので、よろしければご参照頂ければと思います。