Sub フォルダ内のファイル名やファイルパスを取得()
Dim intIchi As Integer
Dim strFolderpass As String
Dim objfFSO As Object
Dim objFiles As Object
Dim objFile As Object
'ファイル名一覧を出力する行番号を指定します。
intIchi = 3
'対象フォルダのファイルパスがあるセルを指定し、値を代入します。
strFolderpass = Range("B1").Value
'指定範囲の値をクリアします。
Range("A3:B10000").Clear
'対象フォルダのファイルパスの値があれば処理をおこないます。
If strFolderpass = "" Then
MsgBox "対象フォルダのファイルパスがありません。ファイルパスを入力してください。"
Else
'FileSystemObjectはファイルやフォルダを操作する専用のオブジェクトです｡インスタンスにセットします。
Set objfFSO = CreateObject("Scripting.FileSystemObject")
'対象フォルダのファイルオブジェクトをセットします。
Set objFiles = objfFSO.GetFolder(strFolderpass).Files
'ファイル情報を出力します。
For Each objFile In objFiles
Cells(intIchi, 1) = objFile.Name
Cells(intIchi, 2) = objFile.Path
intIchi = intIchi + 1
Next objFile
End If
Set objfFSO = Nothing
Set objFiles = Nothing
Set objFile = Nothing
End Sub
Sub 各ブックのシート名一覧をまとめ用ブックへ出力する()
Dim objWorkbook As Workbook
Dim objSheetName As Object
Dim i As Integer
Dim strBookList As Variant
Dim intLastRowNum As Integer
Dim intLastRowNum2 As Integer
Dim strBookPassList As String
Dim strSheetNameList As String
'別ブック一覧があるシート名を指定します。
strBookPassList = "別ブックパス一覧"
'出力先のシート名を指定します。
strSheetNameList = "別ブックシート名一覧表"
With ThisWorkbook
'B列を対象に最終行数を取得します。
intLastRowNum = .Sheets(strBookPassList).Cells(Rows.Count, 2).End(xlUp).Row
'出力先のシートA列を対象に最終行数を取得します。
intLastRowNum2 = .Sheets(strSheetNameList).Cells(Rows.Count, 1).End(xlUp).Row
'別ブック一覧があるシートの３行目からパスを取得します。
For i = 3 To intLastRowNum
'別ブックパスを取得します。
strBookList = .Sheets(strBookPassList).Cells(i, 2).Value
'別ブックを開きます。
Set objWorkbook = Workbooks.Open(strBookList)
'Sheetsコレクションから1シートづつオブジェクトを取得します。
For Each objSheetName In objWorkbook.Sheets
'出力先シートのA列へ対象ブックのパスを出力します。
.Sheets(strSheetNameList).Cells(intLastRowNum2, 1).Value = strBookList
'出力先シートのA列へ対象ブックのシート名を出力します。
.Sheets(strSheetNameList).Cells(intLastRowNum2, 2).Value = objSheetName.Name
intLastRowNum2 = intLastRowNum2 + 1
Next
Next i
End With
'範囲選択を解除します。
Application.CutCopyMode = False
'オブジェクトを解放します。
Set objWorkbook = Nothing
End Sub
コメントを残す