【Excel VBA】カンタン！Excelにまとめた連絡先一覧を編集しOutlookの連絡先へ反映させる

前回の「【Excel VBA】カンタン！Outlookの連絡先をExcelワークシートへ取り込む」の続編として、今度は反対に出力したExcelワークシートの連絡先を編集し、その内容をOutlook連絡先へ反映させる方法をご紹介します。

Excel側の連絡先一覧をOutlookの連絡先へ反映する方法について

今回もVBAの実装先はExcelブック側となります。
前回Excelに出力した連絡先一覧を使いますので、準備ができていない方はお手数ですが前回の記事を参考に連絡先一覧を用意してください。

【Excel VBA】カンタン！Outlookの連絡先をExcelワークシートへ取り込む

サンプルシナリオとしては、組織改組で部署名が変更、統合したという前提で以下のように部署名を変更をしたいと思います。

を↓に変えます。

今回の処理フローは以下の通りとなります。
第一メールアドレスをキーにして一致した連絡先情報を更新する方法となりますので、メールアドレスの変更はできないことに注意してください。

①Excelブック(VBA) →　このメアドと一致した人の連絡先に反映してね。　→ Outlook　ちょいまち。
②Excelブック ←　メアドと一致した人の連絡先は更新したよ。一致しなかった人はしてないけどね。　← Outlook　処理できた。

今回Outlookの連絡先を更新するにあたり注意すること

Outlookの連絡先を更新する際は必ずバックアップを行い、万が一誤った情報に変わってしまった場合に切り戻しが行えるようにしましょう。

Outlook上にて以下の順で操作をするとcsvファイル形式かPST形式で出力することができますのでご参考ください。

「ファイル」＞「開く/エクスポート」＞「インポート/エクスポート」＞「ファイルにエクスポート」＞「コンマ区切り値」

「ファイル」＞「開く/エクスポート」＞「インポート/エクスポート」＞「ファイルにエクスポート」＞「Outlookデータファイル（PST）」

ではバックアップができたら早速実装をして動かしてみましょう。

Excel VBAからOutlookを操作するための下準備

①まずExcelを起動し、「開発」タブをクリックします。

②VBEの画面が開いたら、メニューから「ツール」>「参照設定」を選択します。

③「Microsoft Outlook XX.X Object Library」を探してチェックボックスにチェックし「OK」をクリックします。

以上です。

VBAを実装する

続いてVBAを実装します。

今回VBAは以下の通りとなります。
なお、VBAはこちらを参考にしカスタマイズを行いました。

Sub Outlookの連絡先を更新する()

    'Outlook用の定義
    Dim olApp As Outlook.Application
    Dim olNamespace As Outlook.Namespace
    Dim olFolder As Outlook.MAPIFolder
    Dim olConItems As Outlook.Items
    Dim olItem As Object
    
    'Excel用の定義
    Dim wbBook As Workbook
    Dim wsSheet As Worksheet
    
    Dim lnContactCount As Long
    
    Dim strDummy As String
    
    'スクリーンの更新は行われません。
    Application.ScreenUpdating = False
    
    'Excelのブックとワークシートのオブジェクトを設定します。
    Set wbBook = ThisWorkbook
    Set wsSheet = wbBook.Worksheets(1)

    
    'Outlookオブジェクトを設定し、MAPI名前空間を介してOutlookの連絡先一覧を取得します。
    Set olApp = New Outlook.Application
    Set olNamespace = olApp.GetNamespace("MAPI")
    Set olFolder = olNamespace.GetDefaultFolder(olFolderContacts)
    Set olConItems = olFolder.Items
            
    '取得結果を記述する行番号を指定します。2行目のセルから開始されることになります。
    lnContactCount = 2
    wsSheet.Activate
    
    Dim rc As Integer
    rc = MsgBox("連絡先を更新しますか？", vbYesNo + vbQuestion, "確認")
    
    If rc = vbYes Then

        '連絡先一覧の件数分繰り返す。
        For i = lnContactCount To Cells(1, 1).End(xlDown).Row
            '連絡先のメールアドレスをキーにして連絡先を検索
            Set olItem = olConItems.Find("[Email1Address]='" & Cells(i, 8) & "'")
            
            If TypeName(olItem) = "ContactItem" Then
                    With olItem
                        '連絡先の各項目へ値を代入
                        .CompanyName = Cells(i, 1)
                        .Department = Cells(i, 2)
                        .LastName = Cells(i, 3)
                        .YomiLastName = Cells(i, 4)
                        .FirstName = Cells(i, 5)
                        .YomiFirstName = Cells(i, 6)
                        .FullName = Cells(i, 7)
                        .Email1Address = Cells(i, 8)
                        .Email1DisplayName = Cells(i, 9)
                        .MobileTelephoneNumber = Cells(i, 10)
                    End With
                    'Outlookの連絡先へ保存
                    olItem.Save
            End If
        Next
        
        'Null out the variables.
        Set olItem = Nothing
        Set olConItems = Nothing
        Set olFolder = Nothing
        Set olNamespace = Nothing
        Set olApp = Nothing
        
        'Sort the rows alphabetically using the CompanyName or FullName as appropriate, and then autofit.
        With wsSheet
            .Range("A2", Cells(2, 6).End(xlDown)).Sort key1:=Range("A2"), order1:=xlAscending
            .Range("A:F").EntireColumn.AutoFit
        End With
                
        'Turn screen updating back on.
        Application.ScreenUpdating = True
        
        MsgBox "Outlook連絡先の反映が完了しました！", vbInformation


    Else
        MsgBox "処理を中断します"
    End If
    
End Sub

実装手順は以下の通りです。今回はExcel側にこのVBAを実装します。
①Excelを新規に開き、「開発」タブをクリックし、「VisualBasic」をクリックします。
もしくはショートカットキー「Alt」＋「F11」でもOKです。

②標準モジュールを追加します。
左ペインのVBAProjectを右クリックし、「挿入」、「標準モジュール」を選択します。

③右ペインのウインドウに上記のマクロを入力します。

こちらで完了です。

早速実行してみよう

①「開発」タブの「マクロ」をクリックし「Outlookの連絡先を更新する」を選択し、「実行」をクリックします。

②確認画面がでたら「はい」を選択し、以下のメッセージがでたら完成です！

Outlookの連絡先を確認してみる

さっそくOutlookの連絡先が更新されているか確認してみましょう。

変更前の部署名は以下の通りです。

変更後は、

はい！変わっていますね！

なお、Outlookの連絡先の情報反映にタイムラグがありすぐに反映されない場合があります。その場合には別の人の連絡先を読み込んだ後に元の人の連絡先に戻ると更新がされますので、試してみてください。

今回のVBAについて説明

Excel側の連絡先一覧の件数分処理を繰り返すように設定します。

For i = lnContactCount To Cells(1, 1).End(xlDown).Row

で、「Find」メソッドを使用し、連絡先の第一メールアドレスをキーにしてOutlookの連絡先のレコードを検索します。
「Find」メソッドの構文は以下の通りです。

oFolder.Items.Find("[項目] = '値'")

項目[Email1Address]が第一メールアドレスのことで、Cells(i, 8)はメールアドレスが格納されているセルの値を参照しています。

Set olItem = olConItems.Find(“[Email1Address]='” & Cells(i, 8) & “‘”)

オブジェクトolItemのタイプが”ContactItem”だったときにセルの値をOutlookに格納する処理を行います。なお、検索該当なしの場合は“Nothing”となり、この場合はスキップされます。

If TypeName(olItem) = “ContactItem” Then

.CompanyName = Cells(i, 1)
.Department = Cells(i, 2)
.LastName = Cells(i, 3)
.YomiLastName = Cells(i, 4)
.FirstName = Cells(i, 5)
.YomiFirstName = Cells(i, 6)
.FullName = Cells(i, 7)
.Email1Address = Cells(i, 8)
.Email1DisplayName = Cells(i, 9)
.MobileTelephoneNumber = Cells(i, 10)

仕上げにOutlookの連絡先へ保存します。

olItem.Save