Function EXTGPTMATOME(rangInput As Range, strLang As String)
Dim objhttp As Object
Dim APIKey As String
Dim apiUrl As String
Dim strTextToPredict As String
Dim strRequestBody As String
Dim strResponse As String
Dim strModel As String
Dim strInput As String
Dim strOutput As String
Dim arrInput As Variant
Dim temp As Variant
Dim temp2 As Variant
Dim i As Integer
Dim intCount As Integer
Dim intMaxTokens As Integer
'APIキーを入力します。
APIKey = "sk-****************************************"
'ChatGPTのAPIから出力される最大文字数を指定します。
intMaxTokens = 1000
'ChatGPT APIのモデルを指定します。
strModel = "text-davinci-003"
'要約条件を取得します。セル改行コードは"\n"に置き換えます。
strTextToPredict = Replace(strLang, Chr(10), "\n")
'ChatGPTへの質問を作成します。
strTextToPredict = "以下の文を" & strTextToPredict & "まとめてください。"
'入力レンジが一つか複数であるかを判定します。
If rangInput.Count = 1 Then
'一つであれば要約文字列を変数に代入します。
strInput = rangInput.Value
Else
'複数であれば配列として変数に代入します。
arrInput = rangInput
'要約対象の文章を取得します。セル改行コードは"\n"に置き換えます。
For i = 1 To UBound(arrInput, 1)
strInput = strInput & "\n" & Replace(arrInput(i, 1), Chr(10), "\n")
Next
End If
'要約対象の文章と質問文を結合します。
strTextToPredict = strTextToPredict & "\n" & strInput & "\n"
Debug.Print strTextToPredict
'リクエスト先のURLを設定します。
apiUrl = "https://api.openai.com/v1/completions"
'XMLHTTPオブジェクトをセットします。
Set objhttp = CreateObject("MSXML2.XMLHTTP")
With objhttp
'リクエストのヘッダーを設定します。
.Open "POST", apiUrl, False
.setRequestHeader "Content-Type", "application/json"
.setRequestHeader "Authorization", "Bearer " & APIKey
' リクエスト文を作成します。
strRequestBody = "{""model"":""" & strModel & """, ""prompt"":""" & strTextToPredict & """, ""max_tokens"":" & intMaxTokens & ", ""temperature"":0.5, ""top_p"":1}"
'リクエストを送信します。
.send strRequestBody
'APIからのレスポンスが返るまで待ちます。
Do While .readyState <> 4
DoEvents
Loop
'レスポンス情報をデバッグします｡不要であれば削除してください｡
Debug.Print .responseText
'レスポンスのテキスト情報をExcel出力用変数に代入します。
strResponse = .responseText
End With
'Json形式のデータの内回答テキストがある位置から分割します。
temp = Split(strResponse, """text"":""")
'配列数を取得します。
intCount = UBound(temp)
'配列分処理を繰り返します。
For i = 1 To intCount
If i = intCount Then
'最後の回答を代入します。
temp2 = Split(temp(i), """,""")
strOutput = strOutput & Chr(10) & Replace(Replace(temp2(0), "\n", Chr(10)), "\", "")
Else
'最後の回答以外を代入します。
strOutput = strOutput & Chr(10) & Replace(Replace(temp(i), "\n", Chr(10)), "\", "")
End If
Next i
'関数に回答内容を渡します。
EXTGPTMATOME = strOutput
End Function
コメントを残す